crear una medida que me busque una hora que le corresponda a un valor maximo de un rango de datos

Hola Mirian,

Me he preparado un escenario semejante al tuyo pero "de juguete". Parto de la siguiente tabla:

La he leído con Power BI y le he dado como nombre "data".

Mi primer impulso ha sido generar una tabla agregada que muestre, para cada período, el valor máximo de la demanda y la hora correspondiente (para poder extraer después esta información según convenga). Extraer el valor máximo de la demanda es fácil con la función SUMMARIZE:

Tabla1 = SUMMARIZE(
        data;
        data[Período];
        "Max"; MAX(data[Demanda])
    )

Ahora bien ¿cómo extraer también la hora? Imagino que debe haber formas más simples, pero la que se me ha ocurrido (y funciona) es hacer un cross join de la tabla anterior con la tabla original, haciendo coincidir el valor de "Max". Esto lo podemos conseguir con la función GENERATE:

Tabla2 = 
    GENERATE(
        SUMMARIZE(
            data;
            data[Período];
            "Max"; MAX(data[Demanda])
        );
        SELECTCOLUMNS(
            data;
            "Hora"; data[Hora];
            "Max2"; data[Demanda]
        )
    )

Fíjate que en la columna "Max" solo aparecen los valores máximos obtenidos para cada período, mientras que en Max2 se muestran los valores de cada "Hora".

Ahora basta con filtrar esta tabla de forma que "Max" sea igual a "Max2" (es decir, nos quedamos con la fila correspondiente al valor máximo):

Tabla2 = 
FILTER(
    GENERATE(
        SUMMARIZE(
            data;
            data[Período];
            "Max"; MAX(data[Demanda])
        );
        SELECTCOLUMNS(
            data;
            "Hora"; data[Hora];
            "Max2"; data[Demanda]
        )
    );
    [Max] = [Max2]
)

Habría que eliminar la columna Max2, claro.

No sé si este enfoque te sirve. Una vez obtenida esta tabla, podrías extraer sus valores para añadirlos en tus objetos gráficos. Ya me contarás...

Un saludo

Daniel Burrueco

Si quieres hacerlo con una medida, puedes buscar el valor máximo de la demanda y extraer el valor de la hora correspondiente a dicho valor:

Hora pico Mañana = 
    VAR
        MaxDemanda = 
            CALCULATE(
                MAX(data[Demanda]);
                data[Período] = "Mañana"
            )
    RETURN
        CALCULATE(
            MIN(data[Hora]);
            data[Demanda] = MaxDemanda
        )

Con el "MIN(data[Hora])" estamos extrayendo la primera hora para la que se da la coincidencia (podría ocurrir que hubiese más de una hora con el máximo).

Dime si este enfoque te va mejor

Un saludo

Daniel

Puedes dar formato a un campo seleccionándolo en la columna de campos y configurando la opción "Formato" que encuentras en la cinta superior de herramientas (pestaña "Herramientas de columnas" del nuevo ribbon).

En el peor de los casos, puedes dar formato al campo creando una medida con FORMAT:

https://www.interactivechaos.com/dax/function/format

Saludos

Daniel

Por cierto, no sé cómo no se me ocurrió ayer que también puedes extraer la hora buscada con la función LOOKUPVALUE:

https://www.interactivechaos.com/dax/function/lookupvalue

Hora pico Mañana = 
    VAR
        MaxDemanda = 
            CALCULATE(
                MAX(data[Demanda]);
                data[Período] = "Mañana"
            )
    RETURN
        LOOKUPVALUE(
            data[Hora];
            data[Demanda]; MaxDemanda
        )

Un saludo

Daniel

En ese caso debe ser por la configuración regional de tu ordenador. Lo que puedes hacer es asignar otra configuración a tu informe: Archivo > Opciones y configuración > Opciones > Configuración regional, y cambiar la opción del "idioma del modelo". Como ves en el fondo de la siguiente imagen, a mí me salen las horas de tu modelo de datos en el formato que deseas: